OData for CDS with Parameters

Hello! How are you.

I had the same problem in one of my last projects and the request was to use the odata in a Fiori APP.

In order to not have to change the way the Fiori team was used to call the odata we solve the problem with other aproach.

The main view was a regular cds with parameter (p_lang) as we are in a 7.40 versión and the parameter  $session.system_language is not avaliable.

define view ZCP_CDS_xxxxxx with parameters p_lang : abap.lang
  as select from zcp_t_xxxx as table1 left outer join lfa1 as prov on table1.table1 = prov.lifnr 
                                            left outer join adr6 as email  on prov.adrnr      = email.addrnumber
                                            //Descripciones
                                            left outer join ZCDS_yyyyyy( p_lang : $parameters.p_lang ) as f4tipprod      on table1.tipoprod      = f4tipprod.val 
	association [1..*] to ZCP_CDS_JJJJJJ  as _table3 on $projection.key1 = _PRODCOP.key1
{

	table1.key1
} 

We have a main table "zcp_t_xxxx as table1"  and we access another table that also has the parameter language "ZCDS_yyyyyy".

Besides we have another view ZCP_CDS_JJJJJJ that also have in its definition the parameter (omited as is almost the same definition as ZCP_CDS_XXXXX)

Both views are published as entities in the service (segw) so we want to make calls like

/sap/opu/odata/sap/ZXXXXX_SRV/XXXXXXSet

Query on the main table

and

/sap/opu/odata/sap/ZXXXXX_SRV/XXXXXXSet('9012401')/JJJJJJJSet

Query on the second table using the association defined in the main table.

To solve the problem of the parameter we have to redefine the method. IF_SADL_GW_QUERY_CONTROL~SET_QUERY_OPTIONS in our DPC_EXT class.

The implementation purpose is to add programatically the parameter p_lang (sy-lang)

METHOD if_sadl_gw_query_control~set_query_options.

    DATA: lt_parameters TYPE if_sadl_public_types=>tt_entity_parameters,
          ls_parameter  LIKE LINE OF lt_parameters,
          lt_para       LIKE ls_parameter-parameters.

    "Casting in order to get the navigation properties
    DATA: lo_query TYPE REF TO cl_sadl_gw_query_options.
    lo_query ?= io_query_options.
    lo_query->get_navigation_info( IMPORTING et_navigation_path = DATA(lt_navpath)  ).


    "We add all the entities necessary to arrive to the current one
    DATA: lt_entity LIKE TABLE OF iv_entity_set.
    IF lt_navpath IS NOT INITIAL.
      lt_entity = VALUE #( FOR lw IN lt_navpath  ( CONV #( lw-source_entity_type && 'Set' ) )  ).
    ENDIF.

    "Add the current one
    APPEND iv_entity_set TO lt_entity.

	"Add the parameter p_lang to all the entities that need the parameter
    LOOP AT lt_entity INTO DATA(ls_entity).
      CASE ls_entity.
        WHEN    'xxxxxxSet'                   OR
                'jjjjjjjjjjSet'.
          APPEND VALUE #( entity_alias = ls_entity parameters = VALUE #( ( name = 'P_LANG' value = sy-langu ) ) ) TO lt_parameters.
        WHEN OTHERS.
      ENDCASE.
    ENDLOOP.
	
    IF lt_parameters IS NOT INITIAL.
      io_query_options->set_entity_parameters( lt_parameters ).
    ENDIF.

  ENDMETHOD.