Skip to Content

In the ABAP Keyword Documentation, in SCN blogs or in other demos you might have recognized the usage of class CL_DEMO_OUTPUT. This blog in two parts will explain that class a little bit closer. Part 1 explains its usage while Part 2 will have a look behind the scenes.

 

Disclaimer

The classes described here are not intended for productive usage. You might use them in demonstration programs, local test programs or for temporary testing in productive programs. You must not use them productively in productive programs.

 

Motivation

From the beginning, ABAP lacked a simple way of outputting data for test or demonstration purposes (System.out.println(…) in Java or printf in C so to say). In the old SAP GUI days of classical dynpros you could use the MESSAGE statement for short outputs in information messages or you mainly (mis)used the WRITE statemtent for creating list output. Simple and straightforward – but only in executable programs (reports)! Already in classical dialog programs this kind of WRITE output failed. Even worse in service oriented programming using classes. And nowadays when programming ABAP in ADT for UI5 and FIORI? Don’t ask. The class CL_DEMO_OUTPUT was invented as a demonstration, how this lack can be circumvented.

 

Methods of CL_DEMO_OUTPUT

The methods of class CL_DEMO_OUTPUT create simple outputs of data in example programs without the need of classical lists. The class can be used via static methods and instance methods. The following methods create output in an output stream: 

  • Methods BEGIN_SECTION, NEXT_SECTION, and END_SECTION create headers and open or close header levels.
  • Methods WRITE_DATA, WRITE_TEXT, WRITE_XML, WRITE_JSON, and WRITE_HTML write different kinds of output into the output stream.
    • With method WRITE_DATA you can write elementary data objects (no reference variables), structures with elementary components, and internal tables of such line types.
    • The other methods create formated outputs of texts, XML, JSON, or HTML data.
  • Method WRITE is generic. It handles ABAP data as well as texts (in non proportional format).
  • Methods DISPLAY_… (available  as static methods only) work as WRITE_…, but close the current output stream and open a new one. If a SAP GUI is available, the output is displayed in a window.
  • Method LINE creates a horzontal line.
  • Method DISPLAY closes the current output stream and opens a new one. If a SAP GUI is available, the output is displayed in a window. Optionally you can also pass data to DISPLAY as you can do for WRITE.
  • Method GET works like DISPLAY but does not display the data. Instead the formated output data are returned in a text string and can be handled further.

The standard output format is HTML. Optionally you can choose a simple text format with tabulators and line breaks. You choose the format with method SET_MODE for the static methods or using the input parameter MODE of the factory method NEW for the instance methods.

The class CL_DEMO_OUTPUT is available in release 7.03/7.31 since SP07 and in higher releases. It has a class documentation.

 

Code Examples

The most simple and common type of usage might look as follows:

SELECT *
       FROM scarr
       INTO TABLE @DATA(carriers).

cl_demo_output=>display( carriers ).

The output is:

 

/wp-content/uploads/2016/05/out1_947829.gif

 

A program using more than one static method of CL_DEMO_OUTPUT might look as follows:

SELECT *
       FROM scarr
       INTO TABLE @DATA(carriers).

CALL TRANSFORMATION id SOURCE carriers = carriers
                       RESULT XML DATA(xml).

cl_demo_output=>begin_section( `Some Text` ).
cl_demo_output=>write_text( |blah blah blah \n| &&
                            |blah blah blah| ).
cl_demo_output=>next_section( `Some Data` ).
cl_demo_output=>begin_section( `Elementary Object` ).
cl_demo_output=>write_data( carriers[ 1 ]-carrid ).
cl_demo_output=>next_section( `Internal Table` ).
cl_demo_output=>write_data( carriers ).
cl_demo_output=>end_section( ).
cl_demo_output=>next_section( `XML` ).
cl_demo_output=>write_xml( xml ).
cl_demo_output=>display( ).

Since this looks very ugly, it is better to use the instance methods instead of the static methods if you call more than 3 to 4 methods of the class within a program:

SELECT *
       FROM scarr
       INTO TABLE @DATA(carriers).

CALL TRANSFORMATION id SOURCE carriers = carriers
                       RESULT XML DATA(xml).

cl_demo_output=>new(
  )->begin_section( `Some Text`
  )->write_text( |blah blah blah \n| &&
                 |blah blah blah|
  )->next_section( `Some Data`
  )->begin_section( `Elementary Object`
  )->write_data( carriers[ 1 ]-carrid
  )->next_section( `Internal Table`
  )->write_data( carriers
  )->end_section(
  )->next_section( `XML`
  )->write_xml( xml
  )->display( ).

Both give the same output:

/wp-content/uploads/2016/05/out2_947830.gif

 

You might ask yourself two things:

 

  • How can static methods and instance methods have the same name?

    The instance methods are interface methods. Method NEW returns a reference variable of type IF_DEMO_OUTPUT. This interface is implemented by CL_DEMO_OUTPUT. The interface methods have the same names as the static methods of the class.

  • Why can you chain these methods? 

    For this convenience, each instance method returns the self reference me.

 

If you want a more simplistic output, you can switch to text mode:

SELECT *
       FROM scarr
       INTO TABLE @DATA(carriers).

cl_demo_output=>new( 'TEXT'
  )->display( carriers ).


/wp-content/uploads/2016/05/out3_947846.gif

 

If you want to deal with the resulting formatted data yourself, you use GET instead of DISPLAY:

SELECT *
       FROM scarr
       INTO TABLE @DATA(carriers).

DATA(html) = cl_demo_output=>get( carriers ).

cl_abap_browser=>show_html( html_string = html ).

You can also examine and run the following programs to get a complete overview of all possiblities:

 

  • DEMO_USAGE_OUTPUT_STATIC
  • DEMO_USAGE_OUTPUT_INSTANCE

Examples of Usage

An example how CL_DEMO_OUTPUT can be used by a framework is provided by the ABAP Keyword Documentation in ADT (aka ABAP in Eclipse). If an example of the ABAP Example Library uses CL_DEMO_OUTPUT, the documentation framework allows you to execute the example and displays the output. This is done by getting the HTML output from CL_DEMO_OUTPUT  and merging it into the (non SAP GUI) documentation display.

/wp-content/uploads/2016/05/out4_947848.gif

Another example is quite remarkable. CL_DEMO_OUTPUT made it to the stage in SAP Teched 2013!

Here a snapshot from Dr. Vishal Sikka’s keynote:

/wp-content/uploads/2016/05/out5_947867.jpg

I guess it is quite safe to assume that nobody recognized how that demo output was created  😉 .

(B.t.w., see  AMDP, Comparison of SQLScript with Open SQL for a closer look at the performance results of that example; The bad ABAP results above come from nested SELECT loops …).

 

Conclusion

The methods of CL_DEMO_OUTPUT can serve for quick and dirty outputs in tests or in demo programs. But the class is not made for productive usage. Particularly, CL_DEMO_OUTPUT and the framework behind are not prepared for handling large amounts of data.

Note

CL_DEMO_OUTPUT has a little sister CL_DEMO_INPUT that can be used for simple inputs of elementary values.

 

 

To report this post you need to login first.

6 Comments

You must be Logged on to comment or reply to a post.

  1. Sandra Rossi

    Hello Horst, thank you for detailing this useful test class.

    Is it planned to make this class work for background jobs too, to output the data into a spool request(i.e. output tables using _ and | characters, as for ALV)? Currently, in my system (7.40 SP 7), it doesn’t output anything in background, and that would be very useful for medium-long duration tasks.

    Thanks!

    Sandra

    (0) 
      1. Sandra Rossi

        Thanks. As the result is HTML, it requires a few manual actions to display it (menu list -> save as -> clipboard, then open a text processing software, paste, remove “line feed” characters, save as an html, and display it). It’s not so complex as I don’t need it so frequently, but the task is tedious when I need it… and I’m lazy 😉

        (0) 
        1. Horst Keller Post author

          Hmm, there is already a text mode available that returns plain text instead of HTML. I could modify the existing textual output mode by introducing | between columns and _ between lines and sell that as an additional list mode, hmm, not too much work. Maybe. But can’t you use the text mode anyway. Should be enough for tests. Already now, you can GET the text output into an internal table (split the string at |\n|) and WRITE that to spool.

           

          (1) 
          1. Sandra Rossi

            Oh sorry, I hadn’t seen the section about SET_MODE. It’s just what I needed. Having borders would be nice, but I can easily live without it. Thanks a lot!

            (0) 

Leave a Reply