How to select a specific session to do SAP GUI Scripting activities inside it

Søren West

Hello Søren,

welcome in the world of SAP GUI Scripting. Sure can I help you, as attachment two scripts.

The first script starts three different transaction codes in three new sessions. Then it starts an independent script, with the connection and session number as arguments. Here you can also start, dependently from your transaction code, different scripts. On this way you achieve parallelism.

'-Begin-----------------------------------------------------------------

'-Directives------------------------------------------------------------
Option Explicit

'-Sub Action------------------------------------------------------------
Sub Action(con, ses)

  Dim objShell, RegEx, Matches, con_no, ses_no

  Set RegEx = New RegExp
  RegEx.Pattern = "[0-9]"
  Set Matches = RegEx.Execute(con)
  con_no = Matches(0).Value
  Set Matches = RegEx.Execute(ses)
  ses_no = Matches(0).Value

  Set objShell = Wscript.CreateObject("WScript.Shell")
  objShell.Run "YourScript.vbs " + con_no + " " + ses_no

End Sub


'-Function GetSession---------------------------------------------------
Function GetSession(connection, TAC)

  Dim sessions, session, sessionInfo, j, i

  Set sessions = connection.Sessions()
  '-Loop over sessions--------------------------------------------------
  For Each session In sessions
    If session.Busy() = vbFalse Then
      Set sessionInfo = session.Info()
      If sessionInfo.Transaction() = TAC Then
        Set GetSession = session
      End If
    End If
  Next

End Function

'-Sub Main--------------------------------------------------------------
Sub Main()

  Dim SapGuiAuto, app, connection, session
  Dim session_SE16, session_SE37, session_SE38
  Dim arr

  Set SapGuiAuto = GetObject("SAPGUI")
  If Not IsObject(SapGuiAuto) Then
    Exit Sub
  End If

  Set app = SapGuiAuto.GetScriptingEngine
  If Not IsObject(app) Then
    Exit Sub
  End If

  Set connection = app.Children(0)
  If Not IsObject(connection) Then
    Exit Sub
  End If

  If connection.DisabledByServer = True Then
    Exit Sub
  End If

  Set session = connection.Children(0)
  If Not IsObject(session) Then
    Exit Sub
  End If

  If session.Info.IsLowSpeedConnection = True Then
    Exit Sub
  End If

  session.findById("wnd[0]/tbar[0]/okcd").text = "/oSE16"
  session.findById("wnd[0]").sendVKey 0
  session.findById("wnd[0]/tbar[0]/okcd").text = "/oSE37"
  session.findById("wnd[0]").sendVKey 0
  session.findById("wnd[0]/tbar[0]/okcd").text = "/oSE38"
  session.findById("wnd[0]").sendVKey 0

  Set session_SE16 = GetSession(connection, "SE16")
  arr = Split(session_SE16.ID, "/")
  WScript.Sleep 500
  Action arr(2), arr(3)

  Set session_SE37 = GetSession(connection, "SE37")
  arr = Split(session_SE37.ID, "/")
  WScript.Sleep 500
  Action arr(2), arr(3)

  Set session_SE38 = GetSession(connection, "SE38")
  arr = Split(session_SE38.ID, "/")
  WScript.Sleep 500
  Action arr(2), arr(3)

End Sub

'-Main------------------------------------------------------------------
Main()

'-End-------------------------------------------------------------------

In the independent script the connection and session number are arguments.

'-Begin------------------------------------------------------------------

Set Args = WScript.Arguments
con = Args(0)
ses = Args(1)

Set SapGuiAuto = GetObject("SAPGUI")
If Not IsObject(SapGuiAuto) Then
  WScript.Quit
End If

Set app = SapGuiAuto.GetScriptingEngine
If Not IsObject(app) Then
  WScript.Quit
End If

Set connection = app.Children(CLng(con))
If Not IsObject(connection) Then
  WScript.Quit
End If

If connection.DisabledByServer = True Then
  WScript.Quit
End If

Set session = connection.Children(CLng(ses))
If Not IsObject(session) Then
  WScript.Quit
End If

If session.Info.IsLowSpeedConnection = True Then
  WScript.Quit
End If

MsgBox session.Info.Transaction()

'-End--------------------------------------------------------------------

Best regards
Stefan